9 TRAP 31782
10 ? CHR$(125);"LOAD ";CHR$(34);"C:";CHR$(34)
20 SOUND 3,52,14,8:FOR I=0 TO 2000:NEXT I
21 P=53760:SOUND 0,5,14,8:SOUND 1,7,14,8:POKE P+15,43:FOR I=0 TO 255:POKE P+13,PEEK(40960+I):NEXT I
22 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 3,0,0,0
23 MOTUR=0:PL=0
30 ? :FOR B=0 TO 4:READ A,C:? CHR$(A);CHR$(253):FOR D=0 TO C:NEXT D:NEXT B:DATA 69,100,82,100,82,0,79,0,82,0
40 DIM A$(1):RESTORE 40:? "READY":FOR I=0 TO 2:READ A$:? A$;:FOR C=0 TO 255:NEXT C:NEXT I:DATA R,U,N
50 ? :? "DeCRUSHing":FOR I=0 TO 255:POKE 53274,PEEK(53770):NEXT I:? CHR$(125)
100 DIM C$(1)
101 ? CHR$(125):? "┌───┐":? "|* *|":? "└──┘":? "CASSATE OPERATING SYSTEM 1.2.3":? "2023 BC (C) BY PACT"
102 ? :? "YOU'RE SITTING ON STOOL NEAR THE TABLE WITH ATARI 400 AND TAPE RECORDER ON."
103 ? "THROUGH THE WINDOW YOU CAN SEE REAL WORLD. BEAUTIFUL WORLD..."
104 ? "NOW YOU CAN DO:"
105 ? :? "STATUS MOTORU: ";:IF MOTUR=1 THEN PRINT "ON"
106 IF MOTUR=0 THEN ? "OF"
107 ? :? "A.MOTOR ON":? "B.MOTOR OFF":? "C.LOAD PROGRAM":? "D.RUN PROGRAM":? "E.MAKE DEMO":? "X.EXIT"
108 ? :? "WHAT NOW";:INPUT C$
109 C=0:IF C$<>"" THEN C=ASC(C$)-64
110 IF C=24 THEN GOSUB 20000
111 ON C GOSUB 10000,12000,14000,16000,18000:GOTO 101
10000 REM MOTOR ON
10005 IF MOTUR=0 THEN GOSUB 21000:RETURN 
10010 PRINT "ERROR: MOTUR JUZ JEST ON";CHR$(253);"!!!"
10015 GOSUB 31421
11000 RETURN 
12000 REM MOTOR OFF
12005 IF MOTUR=1 THEN MOTUR=0:SOUND 0,0,0,0:POKE 54018,60:RETURN 
12010 PRINT "ERROR: MOTUR JUZ JEST OF";CHR$(253);"!!!"
12015 GOSUB 31421
13000 RETURN 
14000 REM LOAD PROGRAM
14001 IF MOTUR=0 THEN GOTO 14100
14002 ? "LOADING:";:FOR I=0 TO 50:? ".";:FOR J=0 TO 50:SOUND 0,10,10,10:NEXT J:SOUND 0,0,0,0:NEXT I
14003 ? :? "SORRY, YOUR C64 TAPE HAS WRONG":? "FORMAT..."
14004 ? :? "I USE ONLY REAL TAPE FORMAT FOR":? "PROPER COMPUTER...":PL=1
14005 FOR I=0 TO 5000:NEXT I
14006 RETURN 
14100 ? "YOU CAN'T LOAD PROCESS WHEN MOTOR":? "IS OFF...";
14101 FOR I=0 TO 200:SOUND 3,ABS(10+(I-I*INT(I/12))),14,8:NEXT I
14102 SOUND 3,0,0,0
15000 RETURN 
16000 REM RUN PROGRAM
16001 IF PL=0 THEN ? "NO PROGRAM LOADED YET.":? "LOAD SOMETHING BEFORE RUNNING, PLEASE":GOSUB 31421:RETURN 
16002 ? "PROGRAM RUNNING...";:C=0
16003 ? "ANY KEY STOP IT!"
16004 POKE 764,255
16005 IF PEEK(764)<>255 THEN 16100
16006 POSITION 30,1:? C;:FOR I=0 TO 500+C:NEXT I:C=C+1
16007 IF C>10000 THEN C=0
16008 GOTO 16005
16100 ? "↰OBJECT REFERENCE NOT SET TO AN":? "INSTANCE OF AN OBJECT."
16101 ? "WE'RE JUST COLLECTING SOME ERROR":? "INFO, AND THEN WE'LL RESTART FOR YOU."
16102 FOR I=0 TO 100:? "(";I;"% COMPLETE)";:FOR C=0 TO RND(0)*200:NEXT C:NEXT I:GOSUB 31421
17000 RETURN 
18000 REM MAKE DEMO
18001 GOSUB 31999
19000 RETURN 
20000 REM EXIT
20001 GRAPHICS 2+16
20002 POSITION 1,4:? #6;"   IT IS NOW SAFE"
20003 ? #6;"     TO TURN OFF"
20004 ? #6;"    YOUR COMPUTER"
20005 FOR T=0 TO 200:NEXT T:GRAPHICS 7
20006 SETCOLOR 2,0,0:SETCOLOR 0,0,0
20007 COLOR 1
20008 PLOT 10,48:DRAWTO 150,48
20009 COLOR 0
20010 FOR A=0 TO 15
20011 SETCOLOR 0,0,15-A
20012 PLOT 10+A,48:DRAWTO 20+A,48
20013 PLOT 150-A,48:DRAWTO 140-A,48
20014 NEXT A
20015 GRAPHICS 7
20016 SETCOLOR 2,0,0
20017 SETCOLOR 0,0,0
20018 COLOR 1
20019 PLOT 75,48
20020 FOR A=0 TO 15
20021 SETCOLOR 0,0,A
20022 NEXT A
20023 FOR A=0 TO 15
20024 SETCOLOR 0,0,15-A
20025 NEXT A
20050 GRAPHICS 0:END 
21000 MOTUR=1:SOUND 0,10,0,1:RESTORE 25000:FOR I=0 TO 2:FOR J=0 TO 4
21001 READ A$:? A$;:NEXT J
21002 ? :NEXT I
21003 FOR I=1 TO 1000:NEXT I:POKE 54018,52:RETURN 
25000 DATA v, , ,_,.
25001 DATA ╲,▄,▄,▄,
25003 DATA ●, , , ,●
31421 FOR OPUZNIENIE=1 TO 1000:NEXT OPUZNIENIE:RETURN 
31782 ? "ERROR: WYKRYTO ZLE NACISNIECIE";CHR$(253);"!":TRAP 31782
31783 GOSUB 31421:GOTO 101
31999 POKE 752,1:POKE 82,0:GRAPHICS 0:? "        *** Sober Chessboard ***"
32000 SETCOLOR 1,255,255:SETCOLOR 2,0,0:FOR MALWINA=1 TO 11
32001 FOR LIC=0 TO 19:? " ";:NEXT LIC
32002 FOR LIC=0 TO 19:? " ";:NEXT LIC
32003 NEXT MALWINA:POKE 764,255
32004 ? "      >>> wdus cos <<<     ";:POKE 752,1
32005 IF PEEK(764)=255 THEN 32005
32006 POKE 82,2:POKE 752,0:POKE 764,255:POKE 710,148:POKE 710-1,202:RETURN 
32760 REM ---
32761 REM PRIMA APRILIS COMPO 2023 TAPE RECORDER
32762 REM BY PRIMA APRILIS COMPO TEAM:
32763 REM MONO, SIKOR, MQ, LIZARD, MGR INZ. RAFAL, DELY, PRZ