I pojawiły się kody kontrolne i już się nie da copypastą.
Udźwiękowiłem wybryki z magnetem i dodałem ciągle znikające małe litery w DECRUSHINGu.
9 TRAP 31782
10 ? CHR$(125);"LOAD ";CHR$(34);"C:";CHR$(34)
20 SOUND 3,52,14,8:FOR I=0 TO 2000:NEXT I
21 P=53760:SOUND 0,5,14,8:SOUND 1,7,14,8:POKE P+15,43:FOR I=0 TO 255:POKE P+13,PEEK(40960+I):NEXT I
22 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 3,0,0,0
23 MOTUR=0
30 ? :FOR B=0 TO 4:READ A,C:? CHR$(A);CHR$(253):FOR D=0 TO C:NEXT D:NEXT B:DATA 69,100,82,100,82,0,79,0,82,0
40 DIM A$(1):RESTORE 40:? "READY":FOR I=0 TO 2:READ A$:? A$;:FOR C=0 TO 255:NEXT C:NEXT I:DATA R,U,N
50 ? :? "DeCRUSHing":FOR I=0 TO 255:POKE 53274,PEEK(53770):NEXT I:? CHR$(125)
100 DIM C$(1)
101 ? :? "┌───┐":? "|* *|":? "└──┘":? "CASSATE OPERATING SYSTEM 1.2.3":? "2023 BC (C) BY PACT"
102 ? :? "YOU'RE SITTING ON STOOL NEAR THE TABLE WITH ATARI 400 AND TAPE RECORDER ON."
103 ? "THROUGH THE WINDOW YOU CAN SEE REAL WORLD. BEAUTIFUL WORLD..."
104 ? "NOW YOU CAN DO:"
105 ? :? "STATUS MOTORU: ";:IF MOTUR=1 THEN PRINT "ON"
106 IF MOTUR=0 THEN ? "OF"
107 ? :? "A.MOTOR ON":? "B.MOTOR OFF":? "C.LOAD PROGRAM":? "D.RUN PROGRAM":? "E.MAKE DEMO":? "X.EXIT"
108 ? :? "WHAT NOW";:INPUT C$
109 C=0:IF C$<>"" THEN C=ASC(C$)-64
110 IF C=24 THEN GOSUB 20000
111 ON C GOSUB 10000,12000,14000,16000,18000
114 ? CHR$(125):GOTO 101
10000 REM MOTOR ON
10005 IF MOTUR=0 THEN MOTUR=1:SOUND 0,10,0,1:POKE 54018,52:RETURN
10010 PRINT "ERROR: MOTUR JUZ JEST ON";CHR$(253);"!!!"
10015 GOSUB 31421
11000 RETURN
12000 REM MOTOR OFF
12005 IF MOTUR=1 THEN MOTUR=0:SOUND 0,0,0,0:POKE 54018,60:RETURN
12010 PRINT "ERROR: MOTUR JUZ JEST OF";CHR$(253);"!!!"
12015 GOSUB 31421
13000 RETURN
14000 REM LOAD PROGRAM
15000 RETURN
16000 REM RUN PROGRAM
17000 RETURN
18000 REM MAKE DEMO
19000 RETURN
20000 REM EXIT
20001 GRAPHICS 2+16
20002 POSITION 1,4:? #6;" IT IS NOW SAFE"
20003 ? #6;" TO TURN OFF"
20004 ? #6;" YOUR COMPUTER"
20005 GOTO 20005
31421 FOR OPUZNIENIE=1 TO 1000:NEXT OPUZNIENIE:RETURN
31782 ? "ERROR: WYKRYTO ZLE NACISNIECIE";CHR$(253);"!":TRAP 31782
31783 GOSUB 31421:GOTO 101
32760 REM ---
32761 REM PRIMA APRILIS COMPO 2023 TAPE RECORDER
32762 REM BY PRIMA APRILIS COMPO TEAM:
32763 REM MONO, SIKOR, MQ, LIZARD, MGR INZ. RAFAL, DELY
Edit: A. I jeszcze utworzyłem PACT - Prima Aprilis Compo Team - zamiast wyliczać wszystkich po literce, dwóch.
Ostatnio edytowany przez mono (2023-04-04 19:20:45)
Post's attachmentsPA2023.BAS 2.2 kb, liczba pobrań: 3 (od 2023-04-04)
PA2023.LST 2.05 kb, liczba pobrań: 4 (od 2023-04-04)
Tylko zalogowani mogą pobierać załączniki.
hex, code and ror'n'rol
niewiedza buduje, wiedza rujnuje
