To wszystko tak ladnie wyglada w teorii.

Proponuje wam (tebe - piekna procka, ale...) uruchomienie tej procedury i posluchanie jednego dzwieku na jednym kanale (niech pozostale pracuja na pusto, by nie tlumaczyc tego efektu roznicami w szybkosci procedury).
Potem dodajcie kolejny kanal - niech gra cos innego (a co to za dziwne znieksztalcenia sie pojawiaja?).
Potem trzeci (hm... jeszcze gorzej zaczyna byc - dzwiek ktorego sluchalismy na poczatku brzmi inaczej jakby i to zupelnie).
A Potem czwarty (przeciez tego nie da sie sluchac!!).

Ta procedura nie ma prawa dobrze brzmiec (a SS brzmi!!) z prostej przyczyny nieliniowosci przetwornikow Pokeya (nieliniowosc to moze zle slowo - ale chodzi o to ze wartosci wpisane do sterowania poszczegolnymi generatorami sie nie sumuja i to co jest na wyjsciu nijak sie ma do wartosci wpisanych do rejestrow, chyba ze operujemy pojedynczym, no moze dwoma generatorami).
Metody na to znam dwie (a moze w SS jest inna...):
Pierwsza zastosowana w Sound Trackerze Playerze - przygotowanie tablic dla TRZEch generatorow tak by dawaly liniowa wartosc na wyjsciu Pokeya i zsumowania naszych 4 wartosci "recznie".
Druga niestosowana chyba nigdzie (testowalem ja tez przy pisaniu STP, ale daje cichszy (choc nieznieksztalcony) dzwiek) to ustawienie na wszystkich generatorach dzwieku o najwyzszej mozliwej czestotliwosci i sterowanie jego glosnoscia, zamiast wlaczania bitu bezposredniego sterowania wyjsciem.

No i teraz panowie jak robi to SS, ze tak ladnie brzmi, bo teoretycznie to mozemy sobie procki pisac, a w praniu wyglada to inaczej....

P.S. I kto tu jest nocnym Markiem ?? :)

O ja nie mogę - znalazłem plugina do modułów z FC i SoundMona z Amigi - teraz pora na format decription i analiza playera - może uda się odtworzyć mój ulubiony moduł , który był w Ray of Hope w end parcie, którego napisal od nowa Foster.

Może to sie uda

Adres plugina pod win-ampa :
http://hjem.get2net.dk/surfsmurf/

Tam są przykłady , w katalogu FAVFc jest mod pod nazwą :
J.Hippel-R.s.i_theme.fc4

Posłuchajcie tych utworów , może tędy droga so SS2 ???
Większość ma syntezowane fale i efekty

Iiii... Covox - a co to jest ??

Cala sztuka polega na tym, zeby chodzilo to na Pokeyu. Jak dla mnie player, ktory wymaga dodatkowych urzadzen to jakis wymysl. Rownie dobrze moge sobie przez port joya podlaczyc cale C64 (zeby bylo ciekawiej niz podpinac SIDa) i wysylac tylko sekwencje rozkazow.

Poza tym, chodzi wlasnie aby obejsc ograniczenia Pokeya za pomoca softu, a nie sprzetu - wlasnie tak jak robi to SS. Zrobienie tego na Covoxie wielka sztuka nie jest... wymaga tylko troche pracy przy optymalizacji kodu (trzeba co do cyklu wyliczyc czas wygonywania sie glownej petli playera) - reszta jest czysto mechanicznym pisaniem procedur.

No tak... chyba sluch nie ten juz... :)

W kazdym razie kiedy pisalem STP (a robilem to od podstaw, nie znajac sposobow, srodkow i innych takich procedur - no jedna z Sound Trackera na Atari ST mialem przeanalizowana - ale to inna klasa byla), walczylem z nieliniowoscia przetwornikow Pokeya prawie miesiac, zanim zdecydowalem sie stablicowac to wszystko i grac na trzech generatorach. Moze poprostu na czystych falach (na tyle na ile moga byc czyste przy czej czestotliwosci odtwarzania ;) ) brzmi to lepiej niz przy calych samplowanych instrumentach i dlatego SS tak ladnie gra..... Albo to problemy ze sluchem.
Jednak mimo wszystko wydaje mi sie ze warto by pokusic sie o napisanie i ostre zoptymalizowanie procedury grajacej tak jak SS- moze da sie cos uproscic, przyspieszyc... kto wie. A moze jakis trik na ktory nie wpadl tworca SS, ja bym na poczatek sprobowal tak przerobic SS by stosowal moja tablice i odtwarzal symulowane 4 generatory liniowo - to moze byc ciekawe doswiadczenie, moze sluch sie nam przy tym poprawi ;).

nowsza wersja

;-------------------
;- Synth Player v1.2
;- 12.02.2004
;-------------------

   opt h+
   org $b000

tmp     equ $00
loop    equ tmp+1               ; starszy bajt licznika dla length_Loop

tempo           equ 16          ; tempo, ilosc pelnych przebiegow length_Loop
length_Loop     equ 450         ; dlugosc petli playera, ile ma odegrac wartosci z sampla

audc1           equ $d201       ;rejestry Pokeya
audc2           equ $d203
audc3           equ $d205
audc4           equ $d207

;------------------------------------
;- PROCEDURKA PLAYER-a DLA 4 KANALOW
;------------------------------------

player equ *

;- kanal #1
        clc
del0    lda #0
del0m   adc #0
        sta del0+1
        lda adres0+1
        adc #0
        sta adres0+1

del0_   lda #0
del0m_  adc #0
        sta del0_+1
        lda adres0_+1
        adc #0
        sta adres0_+1
       
adres0  lda $ff00       ; adres 1-ego sampla
adres0_ adc $ff00       ; adres fali modyfikacyjnej
        lsr @           ; dla Covoxa moznaby pominac 'LSR @', wiekszy przedzial wartosci przyjmie Covox
        tax
vol0    lda $ff00,x     ; adres tablicy glosnosci dla 1-ego sampla
ch0     sta audc1

;- kanal #2
        clc
del1    lda #0
del1m   adc #0
        sta del1+1
        lda adres1+1
        adc #0
        sta adres1+1

del1_   lda #0
del1m_  adc #0
        sta del1_+1
        lda adres1_+1
        adc #0
        sta adres1_+1

adres1  lda $ff00       ; adres 2-ego sampla
adres1_ adc $ff00
        lsr @
        tax
vol1    lda $ff00,x     ; adres tablicy glosnosci dla 2-ego sampla
ch1     sta audc2

;- kanal #3
        clc
del2    lda #0
del2m   adc #0
        sta del2+1
        lda adres2+1
        adc #0
        sta adres2+1

del2_   lda #0
del2m_  adc #0
        sta del2_+1
        lda adres2_+1
        adc #0
        sta adres2_+1

adres2  lda $ff00       ; adres 3-ego sampla
adres2_ adc $ff00
        lsr @
        tax
vol2    lda $ff00,x     ; adres tablicy glosnosci dla 3-ego sampla
ch2     sta audc3

;- kanal #4
        clc
del3    lda #0
del3m   adc #0
        sta del3+1
        lda adres3+1
        adc #0
        sta adres3+1

del3_   lda #0
del3m_  adc #0
        sta del3_+1
        lda adres3_+1
        adc #0
        sta adres3_+1

adres3  lda $ff00       ; adres 4-ego sampla
adres3_ adc $ff00
        lsr @
        tax
vol3    lda $ff00,x     ; adres tablicy glosnosci dla 4-ego sampla
ch3     sta audc4

        dey
        beq test

        jmp player

*-----------------

test    lda loop
        beq test_
        dec loop        ; zmniejszenie starszego licznika length_Loop
       
        jmp player

test_   ldy <length_Loop
        lda >length_Loop
        sta loop

        dec tmp         ; tempo wyrazone w liczbie powtorzen petli playera
        beq HEAD

        jmp player

;-----------------------------------
;- dekodowanie patternu
;- ustawienie nowych czestotliwosci
;- glosnosci itp.
;-----------------------------------

HEAD

timer   lda #0
        inc timer+1     ; licznik na potrzeby testow, ustawia po kolei 32 glosnosci i 32 czestotliwosci
        and #$1f
        tax

        tay

* track 0
        lda Adr_Volume,y
        sta vol0+2

        lda frq,x
        sta del0m+1
        clc
shift0  adc #3          ; czestotliwosc fali modyfikacyjnej, zwiekszona o wartosc SHIFT wzgledem glownej czestotliwosci
        sta del0m_+1
        lda #0          ; zerowanie licznika
        sta del0+1
        sta del0_+1
       
        lda Adr_Instr,x
        sta adres0+2
       
        lda >sampl01    ; fala modyfikujaca
        sta adres0_+2
       
* track 1
        ldy #0          ;graj cisze
        lda Adr_Volume,y
        sta vol1+2

        lda frq,x
        sta del1m+1
        clc
shift1  adc #9
        sta del1m_+1
        lda #0
        sta del1+1
        sta del1_+1

        lda Adr_Instr,x
        sta adres1+2
;        lda #0
;        sta adres1+1

* track 2
        ldy #0
        lda Adr_Volume,y
        sta vol2+2

        lda frq,x
        sta del2m+1
        clc
shift2  adc #9
        sta del2m_+1
        lda #0
        sta del2+1
        sta del2_+1

        lda Adr_Instr,x
        sta adres2+2
;        lda #0
;        sta adres2+1

* track 3
        ldy #0
        lda Adr_Volume,y
        sta vol3+2

        lda frq,x
        sta del3m+1
        clc
shift3  adc #9
        sta del3m_+1
        lda #0
        sta del3+1
        sta del3_+1

        lda Adr_Instr,x
        sta adres3+2
;        lda #0
;        sta adres3+1

* let's go
        lda #tempo
        sta tmp

        ldy <length_Loop
        lda >length_Loop
        sta loop
        jmp player

*----
*- tutaj startuje program po wczytaniu do pamieci
*----
main
        lda 20
        cmp 20
        beq *-2

        sei             ;wylaczenie ROM-u i wszystkich przerwan
        lda #0
        sta $d40e
        sta $d400
        lda #$fe
        sta $d301
       
        lda #0          ;zerujemy POKEY
        sta $d208
        lda #3
        sta $d20f

        ldx #33       
        ldy #0          ;ustawiamy 4-bit w tablicach glosnosci dla Pokeya
cnv0    lda volume,y    ;w przypadku Covoxa, nie musielibysmy tego robic
        ora #%00010000
cnv1    sta volume,y
        iny
        bne cnv0
        inc cnv0+2
        inc cnv1+2
        dex
        bne cnv0
       
        ldy #0          ; wyliczamy tablice czestotliwosci
        lda #24         ; pierwsza czestorliwosc
crea    sta frq,y
        clc
        adc #3          ; stala addycja
        iny
        cpy #32
        bne crea
       
        jmp HEAD        ; startujemy od zera (timer=0)
   
   
*----
*- tablice na 4-ej stronie
*----
        org $0400
       
*----
*- instrumenty, czyli 256-bajtowe sample (32)
*----

Sampl00
:256 dta b(1)                 ; fala prostokatna
; :32 dta b(4)
; :32 dta b(8)
; :32 dta b(4)
; :32 dta b(0)

Sampl01                 ; fala trojkatna
:8 dta b(0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,15,14,13,12,11,10,9,8,7,6,5,4,3,2,1,0)

Sampl02                 ; fala modyfikujaca
:8 dta b(0,0,1,1,2,2,3,3,4,4,5,5,6,6,7,7,7,7,6,6,5,5,4,4,3,3,2,2,1,1,0,0)

;- adresy instrumentow
Adr_Instr
:32 dta h(Sampl02)

*----
*- tablice z opuznieniami dla kazdej z czestotliwosci (nuty)
*----

;- oryginalna z INERTI (2 bajtowe wartosci L, H)
; dta l(50),l(53),l(57),l(60),l(63)
; dta l(67),l(71),l(76),l(80)
; dta l(85),l(90),l(95),l(101)
; dta l(107),l(113),l(120),l(127)
; dta l(135),l(143),l(151),l(160)
; dta l(170),l(180),l(190),l(202)
; dta l(214),l(227),l(240),l(254)
; dta l(270),l(286),l(302),l(320)
; dta l(339),l(360),l(381),l(404)
; dta l(428),l(453),l(480),l(508)
; dta l(539),l(571),l(605),l(641)
; dta l(679),l(719),l(762)

*- i dla obecnego playera, wziete z kosmosu :), trzeba je dobrac porzadniej
*- 32 wartosci
frq
:32 brk
       
*----
*- tablica ze starszymi adresami glosnosci (33)
*----
Adr_Volume
dta h(volume,volume+$100,volume+$200,volume+$300,volume+$400,volume+$500,volume+$600,volume+$700)
dta h(volume+$800,volume+$900,volume+$a00,volume+$b00,volume+$c00,volume+$d00,volume+$e00,volume+$f00)
dta h(volume+$1000,volume+$1100,volume+$1200,volume+$1300,volume+$1400,volume+$1500,volume+$1600,volume+$1700)
dta h(volume+$1800,volume+$1900,volume+$1a00,volume+$1b00,volume+$1c00,volume+$1d00,volume+$1e00,volume+$1f00)
dta h(volume+$2000)

*----
*- 33 tablice z glosnosciami, kazda po 256 bajtow
*- dla Pokeya, trzeba ustawic 4-bit we wszystkich tablicach
*----
        org $1000

volume  ins 'volume.tab'

*---
        run main

Cześć!

...Robi się coraz ciekawiej!

Pecus! Ja w każdym razie jestem za... Dobry program z poprawnie napisaną procedurą playera, do tego dźwięk syntetyczny... Mniam!

Do Tebe wysłałem kilka oryginalnych instrumentów z SS...

pozdrowienia,
zielony/waxsoft/bc

Witam!

Oki...
Najpierw do Świętego:
Pomysł przedni ;) , niestety większość fal (synthów) SS jest jednookresowych, więc w ten sposób zniekształcimy tylko falę (a dokładnie będzie słychać tylko te próbki które "przepuści" maska, czyli czasami ciszę). W przypadku wielookresowych (2,4,8 - bo tylko takie będą stroić z pozostałymi) nic się nie zmieni...

Tebe: 24 godz. minęły i nic od Ciebie nie dostałem.. czyli prace trwają! Aż mnie zrzera ciekawość... Siak czy tak wysłałem Ci kolejną łamigłówkę...

Pecuś: A czy to nie jest przypadkiem ten player który odgrywa "spakowane sample" (wiesz, dwie próbki na bajt). O ile dobrze pamiętam to program i źródła były w posiadaniu m.in. Pawła Bulkowskiego (Our5oft).

Czy ktoś z Was ma może dostęp do zapisu trackerowego muzy z gry "Cybernoid I" na C64...  :twisted: Mam diabelski pomysł!!! Szczegóły wkrótce...

pozdrowienia,
zielony/waxsoft/bc

yea 1/2-tusk reprezent

:)

Hey!

   W tym wypadku to chyba nawet 1/3 1/2-tuska!!!!
Inna sprawa, to co ma jedno: "[...] program i źródła były w posiadaniu m.in. Pawła Bulkowskiego (Our5oft)." do drugiego  "zielony: ekkkhee ....przeciez Pecus to tez Our 5oft masa rulez ...."?! :mrgreen:

Ale wspomniałem, bo Daxey kiedyś dostał od Buły (Our5oft)  ;) tenże program wraz z demosem (chyba z "Unity 19xx") I dlatego może ta kiełbasa!...

Odchłań... Choroba, że POLSAT zdjął ten serial z anteny (aj lajket)!

pozdrowienia,
zielony/waxsoft/bc

Zielony:
Sądzę że lepszym pomysłem zamiast mixować 2 próbki na 1 kanał żeby uzyskać dźwięki modulowane jest wprowadzić prosty pomysł o którym pisałem już do tebe:

1. Tablica fali ma być o okersie $7f , czyli 1/2 strony pamięci , i musi być od początku strony !
2.. Fala prostokątna:
:128 dta b($f)
:128 dta b($0)

3.Przykładowa procedura playera:

  lda $84 
   adc #0 
   sta $84 
   lda $80 
   adc #0 
   sta $80
   and #$7f 
   tay 
   ldx $be00,y 
selfmod equ *-2

   lda $bf00,x 
   sta $d201 

4. i w ten prosy sposób wpisując liczbę od 0-$7f do selfmod uzyskujemy 127 krokowy współczynnik wypełnienia fali !!!
$40 - zwykły prostokąt (50/50)
0,$80 - cisza

Sprawdzałem to w praktyce i działa !

Zielony:

chyba nie do konca , bo 1 cykl tracimy gdy adres + y przekracza granice strony - jak y=127 i offset strony =127 to nic nie tracimy !
Mam nadziejez ze o to chodzilo

Druga sprawa - pomysł prosty w swojej idei - szum:

Kod:

  lda $84
   adc #0
   sta $84
   lda $80
   adc #0
   sta $80
   and #$00 
   tay
   ldx $d20a,y
selfmod equ *-2

   lda $bf00,x
   sta $d201 

- i proste i logiczne !!! (nie mamy jedynie wpływu na jego czestotliwosc)
ale mozna np dla perkusji go uzyc

Wiec "and #0" moze sie przydac w wielu przypadkach - oczywiscie nie neguje twojego pomyslu na generacje fal ale 2 fale na siebie mozna nalozyc uzywajac 2 kanalow podobnie jak to robi np CMC na zwyklym POKEYu.

Ja bym obstawal za zwiekszona czestotliwoscia odtwarzania.
A co do nieokresowych fal to efekt ten mozna uzyc jako przesównika fazowego - fala musialaby miec 2 okresy (1 na stronie +$000,2 na stronie +$200)
Faktem jest ze niestety rozcyklowaloby to cala procedurke.

No chyba ze playera bedziemy odtwarzac na IRQ np co 2 linie rastra 
a head umiescilbym tylko w lukach miedzy przerwaniami

naprawde jestem zainteresowany JAKĄKOLWIEK WERSJĄ DO POSŁUCHANIA/TESTOWANIA